COMO hacer DISPENSADOR DE AGUA con ARDUINO

Hace un tiempo atrás publique un video sobre la creación de un dispensador de agua automático comercial, en dicho proyecto había varios detalles que añadir y mejorar,

1. La anterior versión solo aceptaba un solo tipo de monedas. En esta nueva versión se consideró que acepte hasta 6 tipos de monedas.
2. La anterior versión no tenía la opción de  lavado, en cambio esta nueva versión si tiene.
3. La versión anterior no tenía un sensor de nivel de agua, en esta versión si hemos integrado para que haya un límite producto. Cosa que el cliente no insertará más monedas ya que en la pantalla aparecerá un aviso.
4. La versión anterior no tenía un límite de inserción de monedas, es decir, la maquina seguía aceptando infinidad de monedas sin importar el máximo valor. En cambio en este, el máximo valor es de 8 soles. A partir de este último valor la maquina ya no recibirá más monedas.
5. Por último,  pero no menos importante, se ha agradado directamente un conector para las salidas, sin necesidad de hacer puente.

Bien, por el momento estos serían las mejoras que hemos hecho, seguramente más adelante seguiremos mejorando, como por ejemplo agregar un menú de configuración de parámetros.

PASO 1 : SUBIR PROGRAMA BOOTLOADER A UN  ARDUINO UNO

Primero subimos este código BOOTLOADER a un arduino UNO como normalmente subimos cualquier programa a nuestra placa arduino UNO.

PASO 2 : CABLEADO PARA SUBIR GESTOR DE ARRANQUE (BOOTLOADER)

Despues de haber subido el programa anterior, ahora vamos aquemar el gestor de arranque al nuevo microcontrolador que tiene nuestro plc.
Recuerden que para poder usar un microcontrolador nuevo (atmega328P-AU), es necesario subir  un gestor de arranque como también llamado “BOOTLOADER”, esto nos facilitará subir programas en futuras ocasiones. Especialmente cuando se quiere programar desde el IDE de arduino.

finalmente para quemar el bootloader se tendrá que realizar a través de los pines ISP, que prácticamente serían los pines [(MOSI=PIN 11) (MISO = PIN 12) (SCK=PIN 13) (Slave=PIN 10)]. Para subir y quemar el gestor de arranque necesitaremos un arduino UNO ó MEGA y realizar las siguientes conexiones (ARDUINO UNO – PLC LOGO demo).  OJO que este paso solo se hace una sola vez.

#include <LiquidCrystal_I2C.h>
#include <Wire.h>
LiquidCrystal_I2C lcd(0x27, 20, 4);

//==============================  PHYSICAL INPUTS ================================================
const int in1 = 2;  // Sensor de flujo
const int in2 = 3;  // Coin
const int in3 = 4;  // pulsador de lavado
const int in4 = 5;  // pulsador de start de producto
const int in5 = 6;  // pulsador de stop/start
const int in6 = 7;  // Sensor de agua
int in7 = A6;       // IN7
int in8 = A7;       // IN8

//☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼ SWITCH MENUS ☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼
const int left = 8;    //izquierda
const int right = 13;  //derecha
const int intro = 9;   // ok
//===============================================================================================

//==============================  TRANSISTOR OUTPUTS ============================================
const int M_LAV = 14;     // BOMBA PARA LAVADO
const int M_AGUA = 15;    // BOMBA PARA AGUA "producto principal"
const int MONEDERO = 16;  // Receptor de monedas
const int Reserva = 17;   // SALIDA DE RESERVA
//===============================================================================================

//==============================  SENSORS DATA ==================================================
volatile double flujo;  // variable que guarda los pulsos
int filling = 0;        // variable para captar esos pulsos del sensor de flujo en numeros enteros
boolean B_lavAct = false;
//===============================================================================================

//==================================  TIMES =====================================================
int t1 = 0;
int t2 = 0;
int t3 = 0;
int t_lav = 3;  // definir tiempo de lavado  - ahora 3 seg
int t_est = 4;  // definir tiempo de esterilizado - ahora 4seg
int t_thx = 5;  // tiempo mensaje final 5seg
//===============================================================================================

boolean lcdClear = false;  //TO lcd clear

//=================================  ESTATE DATAS ===============================================
boolean E0, E1, E2, E3, E4, E5 = false;        // VARIABLES DE ESTADOS
boolean T01, T12, T23, T34, T45, T50 = false;  // VARIABLES DE TRANSICIONES
//===============================================================================================

//==============================  COIN RECEIVER DATA ============================================
int contadorPulsos = 0;  // Variable para contar los pulsos
int acumuladoSoles = 0;  // Variable para el monto acumulado en Soles
//===============================================================================================

//====================================  STOP DATA ===============================================
byte STOPvalue = 0;  // Variable para contar los pulsos
byte STOPlastState = 0;
boolean STOPstate = false;  // Variable para el monto acumulado en Soles
//===============================================================================================

void setup() {

  lcd.init();
  lcd.backlight();
  lcd.clear();

  Serial.begin(9600);

  //☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼ EXTERNAL INPUTS ☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼☼
  pinMode(left, INPUT);
  pinMode(intro, INPUT);
  pinMode(right, INPUT);
  pinMode(in3, INPUT);
  pinMode(in4, INPUT);
  pinMode(in5, INPUT);
  pinMode(in6, INPUT);
  pinMode(in7, INPUT);
  pinMode(in8, INPUT);

  flujo = 0;                                // Begin with zero, flow sen
  attachInterrupt(0, flujo_pulse, RISING);  //DIGITAL Pin 2: Interrupt 0 || to flow sensor
  attachInterrupt(1, coin_pulse, RISING);   //DIGITAL Pin 3: Interrupt 1 || to coin inputs

  pinMode(M_LAV, OUTPUT);
  pinMode(M_AGUA, OUTPUT);
  pinMode(MONEDERO, OUTPUT);
  pinMode(Reserva, OUTPUT);

  digitalWrite(MONEDERO, 1);
}

void loop() {

  int B_lav = digitalRead(in3);  // sensor de presencia
  int star = digitalRead(in4);   // boton lavado
  int STOP = digitalRead(in5);
  int sen = digitalRead(in6);
  if (STOP != STOPlastState) {
    if (STOP == LOW) {
      STOPvalue++;
    }
  }
  STOPlastState = STOP;
  switch (STOPvalue) {
    case 1:
      STOPstate = true;
      break;
    case 2:
      STOPstate = false;
      STOPvalue = 0;
      break;
  }

  if (sen == 0) {
    digitalWrite(MONEDERO, 0);
    lcd.setCursor(0, 0);
    lcd.print("  NO HAY SUFICIENTE  ");  // aqui cambiar la bienvenida
    lcd.setCursor(2, 1);
    lcd.print("      AGUA           ");
    lcd.setCursor(1, 2);
    lcd.print("VUELVA MAS TARDE    ");
    lcd.setCursor(0, 3);
    lcd.print("    POR FAVOR.       ");

  } else {
    if (E0 == true || E1 == true) {
      if (acumuladoSoles < 8) {
        acumuladoSoles += contadorPulsos;  // acumulamos los pulsos
        contadorPulsos = 0;                // reset pulse
      }
    }

    //█████████████████████████████████████████ INICIALIZACION █████████████████████████████████████████████
    if ((!E1 && !E2 && !E3 && !E4 && !E5) == true) {
      E0 = true;
    }

    //█████████████████████████████████████████ TRANSITION █████████████████████████████████████████████
    //from
    if (E0 == true && (acumuladoSoles >= 1 && acumuladoSoles <= 8)) {
      lcd.clear();
      T01 = true;
      T50 = false;
    }

    if (E1 == true && B_lav == true && B_lavAct == true) {
      lcd.clear();
      T12 = true;
      T01 = false;
    }
    if (E2 == true && t1 == t_lav) {
      lcd.clear();
      T23 = true;
      T12 = false;
    }

    if (E3 == true && star == true) {
      lcd.clear();
      T34 = true;
      T23 = false;
    }
    if (E4 == true && (filling == 2 || filling == 4 || filling == 8)) {
      lcd.clear();
      T45 = true;
      T34 = false;
    }

    if (E5 == true && t3 == t_thx) {
      lcd.clear();
      T50 = true;
      T45 = false;
    }

    //█████████████████████████████████████████ ETAPA █████████████████████████████████████████████
    if (E0 && T01 == true) {
      E0 = false;
      E1 = true;
    }
    if (E1 && T12 == true) {
      E1 = false;
      E2 = true;
    }
    if (E2 && T23 == true) {
      E2 = false;
      E3 = true;
    }
    if (E3 && T34 == true) {
      E3 = false;
      E4 = true;
    }
    if (E4 && T45 == true) {
      E4 = false;
      E5 = true;
    }
    if (E5 && T50 == true) {
      E5 = false;
      E0 = true;
    }

    //█████████████████████████████████████████ ACTUADORES █████████████████████████████████████████████

    if (E0 == true) {  //▄▄▄▄▄▄▄▄▄▄▄▄ E0 REPOSO ▄▄▄▄▄▄▄▄▄▄▄▄
      digitalWrite(M_LAV, 0);
      digitalWrite(M_AGUA, 0);
      flujo = 0;
      filling = 0;

      if (acumuladoSoles == 0) {
        if (acumuladoSoles < 8) digitalWrite(MONEDERO, 1);
        lcd.setCursor(0, 0);
        lcd.print("****BIENVENIDOS*****");  // aqui cambiar la bienvenida
        lcd.setCursor(2, 1);
        lcd.print("INSERTE MONEDAS");
        lcd.setCursor(1, 2);
        lcd.print("SEGUN LOS PRECIOS");
        lcd.setCursor(0, 3);
        lcd.print("      FIJADOS.      ");
      }
    }

    if (E1 == true) {  //▄▄▄▄▄▄▄▄▄▄▄▄ E1 COIN RECEIVER ▄▄▄▄▄▄▄▄▄▄▄▄
      if (acumuladoSoles < 8) digitalWrite(MONEDERO, 1);
      else digitalWrite(MONEDERO, 0);  // desactivamos la alimentacion del receptor de monedas
      lcd.setCursor(3, 0);
      lcd.print("TIENE UN SALDO");
      lcd.setCursor(0, 1);
      lcd.print("DE: S/. ");
      lcd.print(acumuladoSoles);

      if (acumuladoSoles == 2 || acumuladoSoles == 4 || acumuladoSoles == 8) {
        B_lavAct = true;
        if (acumuladoSoles == 2) {
          lcd.setCursor(10, 1);
          lcd.print("= 500 mL ");
          lcd.setCursor(0, 2);
          lcd.print("Presione lavado");
          lcd.setCursor(0, 3);
          lcd.print("PARA CONTINUAR");
        }
        if (acumuladoSoles == 4) {
          lcd.setCursor(10, 1);
          lcd.print(" = 1 Ltr ");
          lcd.setCursor(0, 2);
          lcd.print("Presione lavado");
          lcd.setCursor(0, 3);
          lcd.print("PARA CONTINUAR");
        }
        if (acumuladoSoles == 8) {
          lcd.setCursor(10, 1);
          lcd.print(" = 2 Ltr. ");
          lcd.setCursor(0, 2);
          lcd.print("Presione lavado");
          lcd.setCursor(0, 3);
          lcd.print("PARA CONTINUAR");
        }

      } else {
        lcd.setCursor(1, 2);
        lcd.print("Cantidad no valido");
        lcd.setCursor(0, 3);
        lcd.print("INSERTE MAS MONEDAS");
        B_lavAct = false;
      }
    }

    if (E2 == true) {  //▄▄▄▄▄▄▄▄▄▄▄▄ E2 CLEAN PROCESS ▄▄▄▄▄▄▄▄▄▄▄▄▄
      digitalWrite(MONEDERO, 0);
      digitalWrite(M_LAV, 1);
      lcd.setCursor(1, 1);
      lcd.print("***** LAVANDO ****");
      t3 = 0;
      t1++;
      delay(1000);
    }

    if (E3 == true) {  //▄▄▄▄▄▄▄▄▄▄▄▄ E3 PRESS START  ▄▄▄▄▄▄▄▄▄▄▄▄▄
      digitalWrite(MONEDERO, 0);
      digitalWrite(M_LAV, 0);
      lcd.setCursor(5, 0);
      lcd.print("Press START ");
      lcd.setCursor(1, 2);
      lcd.print("PARA LLENAR AGUA");
      flujo = 0;
    }

    if (E4 == true) {  //▄▄▄▄▄▄▄▄▄▄▄▄ E4 FILLING  ▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄
      digitalWrite(MONEDERO, 0);
      if (STOPstate) digitalWrite(M_AGUA, 0);
      else digitalWrite(M_AGUA, 1);

      if (acumuladoSoles == 2) {
        lcd.setCursor(5, 0);
        lcd.print("LLENANDO...");
        lcd.setCursor(3, 1);
        lcd.print("500 mL de Producto");
        lcd.setCursor(0, 3);
        lcd.print("PROCESO Ltrs. = ");
        lcd.print(flujo);
        if (flujo >= 0.5) {
          filling = 2;
        }
      }
      if (acumuladoSoles == 4) {
        lcd.setCursor(5, 0);
        lcd.print("LLENANDO...");
        lcd.setCursor(3, 1);
        lcd.print("1 Litro de AGUA");
        lcd.setCursor(0, 3);
        lcd.print("PROCESO Ltrs. = ");
        lcd.print(flujo);
        if (flujo >= 1) {
          filling = 4;
        }
      }
      if (acumuladoSoles == 8) {
        lcd.setCursor(5, 0);
        lcd.print("LLENANDO...");
        lcd.setCursor(3, 1);
        lcd.print("2 Litros de AGUA");
        lcd.setCursor(0, 3);
        lcd.print("PROCESO Ltrs. = ");
        lcd.print(flujo);
        if (flujo >= 2) {
          filling = 8;
        }
      }
    }

    if (E5 == true) {  //▄▄▄▄▄▄▄▄▄▄▄▄ E5 COMPLETE  ▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄
      digitalWrite(M_AGUA, 0);
      lcd.setCursor(1, 0);
      lcd.print("  COMPLETO, LLENO");
      lcd.setCursor(3, 2);
      lcd.print("MUCHAS GRACIAS");

      acumuladoSoles = 0;
      t1 = 0;
      t2 = 0;
      t3++;
      delay(1000);
    }

    if (contadorPulsos) {  // Limpia la pantalla cada vez que se detecta un pulso
      lcd.clear();
    }
  }
}
void flujo_pulse() {     //■■■■■■■■■■■■■■■■■■ FLOW SENSOR DETECT ■■■■■■■■■■■■■■■■■■
  flujo += 1.0 / 5350.0;  // este es para ir ajustando la cantidad de litros
}
void coin_pulse() {  //■■■■■■■■■■■■■■■■■■ COIN PULSE DETECT ■■■■■■■■■■■■■■■■■■
  contadorPulsos++;
}