Como hacer contador de aforo de 4 digitos con ARDUINO

Aquí tenemos un contador de 4 dígitos y aquí están los sensores y a medida que van ingresando las personas el conteo se incrementa y cuando salen el conteo va decrementando. Y lo genial de este proyecto es que puedes ajustar el aforo. Además tiene la comunicación rs485 para integrar a cualquier sistema que tiene esa comunicación, por si fuera poco también cuenta con una sirena que suena cuando pasa el límite de aforo.

1. Tensión de alimentación……………………….…………12VDC
2. Corriente de alimentación………………….……………500mA
3. Entradas digitales “sensores” 12VDC………………2
4. Pulsadores de configuracion de aforo………………1
5. Puerto usb de programación……………………………..1
6. Comunicacion Serial…………………………………………….1
7. Comunicación I2C…………………………………………………1
8. Comunicación ISP…………………………………………………1
9. Rs485 Com……………………………………………………………..1
10. Salida a alarma 12V externa………………………………….1
11. Salida buzzer interno………………………………………………1
12. Dimensiones…………………………………….…….………240x100mm
13. Empotrable…………………………………………….………Sí
14. Entorno de programación………………………..……..Arduino IDE
15. Condiciones ambientales min………………………….-10°
16. Condiciones ambientales max…………………..…….55°

#include <EEPROM.h>

int clockpin = 12;  //Cuando ay que leer los bit      SH
int data = 7;       //Envio datos                     DS
int latch = 11;     //indica pin de salida en el chip ST
// no cambiar el const int
const int senIN = 2;   // pin 2 como entrada para el sensor de entrada de personas
const int senOUT = 3;  // pin 3 como entrada para el sensor de salida de personas

const int minus = 4;  // para descontar la capacidad
const int ok = 5;
const int add = 6;

int last_ok = 0;
byte stateOk = 0;
bool stateConfigAforo = false;

int last_state_senIN = 0;   // estado del pulsado  anterior
int last_state_senOUT = 0;  // estado  del pulsado anterior

unsigned int contador = 0;
bool stateIN = false;
bool stateOUT = false;

int aforo = 50;
int direc_aforo = 0;

const int buzzer = 9;
const int sir = 10;

byte contadorDisplay[4] = { 0, 0, 0, 0 };
const int NUM[] = {
  63,   //Numero 0 en binario es : 00111111
  6,    //Numero 1 en binario es : 00000110
  91,   //Numero 2 en binario es : 01011011
  79,   //Numero 3 en binario es : 01001111
  102,  //Numero 4 en binario es : 01100110
  109,  //Numero 5 en binario es : 01101101
  125,  //Numero 6 en binario es : 01111101
  7,    //Numero 7 en binario es : 00000111
  127,  //Numero 8 en binario es : 01111111
  111,  //Numero 9 en binario es : 01101111
  63,   //Numero 0 en binario es : 00111111
  64,   //Numero 0 en binario es : 01000000
  0,    //Numero 0 en binario es : 00000000
};
void setup() {
  Serial.begin(9600);

  pinMode(latch, OUTPUT);
  pinMode(clockpin, OUTPUT);
  pinMode(data, OUTPUT);

  pinMode(buzzer, OUTPUT);
  pinMode(sir, OUTPUT);

  pinMode(senIN, INPUT);
  pinMode(senOUT, INPUT);

  pinMode(minus, INPUT);
  pinMode(ok, INPUT);
  pinMode(add, INPUT);

  EEPROM.get(direc_aforo, aforo);
}

void loop() {
  //Serial.println(aforo);

  if (digitalRead(ok) != last_ok) {
    if (digitalRead(ok) == LOW) {
      stateOk++;
      delay(250);
    }
  }
  last_ok = digitalRead(ok);
  switch (stateOk) {
    case 1:
      stateConfigAforo = true;
      break;
    case 2:
      stateConfigAforo = false;
      stateOk = 0;
      break;
  }

  if (stateConfigAforo == false) {
    if (digitalRead(senIN) != last_state_senIN) {
      if (digitalRead(senIN) == LOW) {
        if (stateOUT == true) {
          if (contador > 0) { contador--; }
          stateOUT = false;
        } else stateIN = true;
      }
    }
    last_state_senIN = digitalRead(senIN);

    if (digitalRead(senOUT) != last_state_senOUT) {
      if (digitalRead(senOUT) == LOW) {
        if (stateIN == true) {
          if (contador < 9999) { contador++; }
          stateIN = false;
        } else stateOUT = true;
      }
    }
    last_state_senOUT = digitalRead(senOUT);

    if (contador >= aforo) {
      tone(buzzer, 5000);  // Pin 9, frecuencia
      digitalWrite(sir, 1);
    } else {
      noTone(buzzer);
      digitalWrite(sir, 0);
    }
    convert();
  }
  if (stateConfigAforo == true) {
    configAforo();
    noTone(buzzer);
    digitalWrite(sir, 0);
  }
}
void configAforo() {
  if (digitalRead(add) == 1) {
    if (aforo < 9999) {
      aforo++;
    }

    delay(150);
  } else if (digitalRead(minus) == 1) {
    if (aforo > 0) {
      aforo--;
    }
    delay(150);
  }
  EEPROM.put(direc_aforo, aforo);
  convert();
}

void convert() {
  if (stateConfigAforo == false) {
    contadorDisplay[0] = contador % 10;          //unidades
    contadorDisplay[1] = (contador / 10) % 10;   //decenas
    contadorDisplay[2] = (contador / 100) % 10;  //centenas
    contadorDisplay[3] = (contador / 1000);      //millar
  }
  if (stateConfigAforo == true) {
    contadorDisplay[0] = aforo % 10;          //unidades
    contadorDisplay[1] = (aforo / 10) % 10;   //decenas
    contadorDisplay[2] = (aforo / 100) % 10;  //centenas
    contadorDisplay[3] = (aforo / 1000);      //millar
  }
  cont();
}
void cont() {
  digitalWrite(latch, LOW);
  shiftOut(data, clockpin, MSBFIRST, NUM[contadorDisplay[0]]);  //und
  shiftOut(data, clockpin, MSBFIRST, NUM[contadorDisplay[1]]);  // dec
  shiftOut(data, clockpin, MSBFIRST, NUM[contadorDisplay[2]]);  //und
  shiftOut(data, clockpin, MSBFIRST, NUM[contadorDisplay[3]]);  // dec
  digitalWrite(latch, HIGH);
}